怎么把金字塔的公式改为文华的？

作者：文华财经来源：cxh99.com 发布时间：2018年11月13日

咨询内容： input:n(1,1,100,1),nmin(10,1,100,1)，K1(20,1,999,0.1),k2(130,1,999,0.1);

CYC:=barslast(date<>ref(date,1))+1;
TR1 := SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(h,1))),ABS(LOW-REF(l,1))),14);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SUM(IF(HD>0 AND HD>LD,HD,0),14);
DMM:= SUM(IF(LD>0 AND LD>HD,LD,0),14);
PDI:= DMP*100/TR1;
MDI:= DMM*100/TR1;
ADX: =MA(ABS(MDI-PDI)/(MDI+PDI)*100,6);
ADXR:=(ADX+REF(ADX,6))/2;

上轨1:REF(HHV(H,k1),1);
下轨1:REF(LLV(L,k1),1);

上轨2:REF(HHV(H,k2),1);
下轨2:REF(LLV(L,k2),1);

PosNum:=1;
t1:=time>opentime(1) and time<143000 ;
t2:=time>=closetime(0)-nmin*100;

//交易条件价格大于130周期高点，动向指标》..,开，价格小于20周期低点平。用dmi过滤
开多条件:=H >=上轨2 and adxr>g and holding=0;
开空条件:=L<=下轨2 and adxr>g and holding=0;

平多条件1:= L<=下轨1;

平空条件1:=h>=上轨1;
//交易系统
开多:buy(开多条件 and t1 and cyc>1 ,PosNum,LIMITR,上轨2);
开空:buyshort(开空条件 and t1 and cyc>1 ,-PosNum,LIMITR,下轨2);
平多1:sell(平多条件1 and holding=PosNum ,0,LIMITR,下轨1);

平空1:sellshort(平空条件1 and holding=-PosNum ,0,LIMITR,上轨1);
收盘平多:sell(t2 ,0,MARKET);
收盘平空:sellshort(t2 ,0,MARKET);

来源:程序化99
文华技术人员：
参考：

N:=1;
NMIN:=10;
K1:=20;
K2:=130;
G:=10;

CYC:=BARSLAST(DATE<>REF(DATE,1))+1;
TR1 := SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(H,1))),ABS(LOW-REF(L,1))),14);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SUM(IF(HD>0 AND HD>LD,HD,0),14);
DMM:= SUM(IF(LD>0 AND LD>HD,LD,0),14);
PDI:= DMP*100/TR1;
MDI:= DMM*100/TR1;
ADX: =MA(ABS(MDI-PDI)/(MDI+PDI)*100,6);
ADXR:=(ADX+REF(ADX,6))/2;

上轨1:REF(HHV(H,K1),1);
下轨1:REF(LLV(L,K1),1);

上轨2:REF(HHV(H,K2),1);
下轨2:REF(LLV(L,K2),1);

POSNUM:=1;
T1:= TIME<1430 ;
T2:=TIME>=1500-NMIN;

//交易条件价格大于130周期高点，动向指标》..,开，价格小于20周期低点平。用DMI过滤
开多条件:=H >=上轨2 AND ADXR>G AND BKVOL=0;
开空条件:=L<=下轨2 AND ADXR>G AND SKVOL=0;

平多条件1:= L<=下轨1;

平空条件1:=H>=上轨1;

开多条件 AND T1 AND CYC>1 ,BK(POSNUM);
开空条件 AND T1 AND CYC>1 ,SK(POSNUM);

平多条件1 AND BKVOL=POSNUM ,SP(BKVOL);
平空条件1 AND SKVOL=POSNUM ,BP(SKVOL);

T2,CLOSEOUT;

来源: WWW.CXH99.COM
文华客服： 1、请问input有文华对应指令吗？
2、开多:buy(开多条件 and t1 and cyc>1 ,PosNum,LIMITR,上轨2);此处的limitr 文华上怎么实现？
网友回复：
1. input不是指令是设置参数，参考2楼源码直接在源码给您进行了定义

正常应该参考下图一方式在参数列表中定义出来

2.使用限价委托参考：

SETSIGPRICETYPE(BK,上轨2);
SETSIGPRICETYPE(SK,下轨2);
SETSIGPRICETYPE(SP,下轨1);
SETSIGPRICETYPE(BP,上轨1);

文件名：111.png