现在 文化转金字塔 策略重新弄了。。帮忙下　[金字塔]

http://www.weistock.com/bbs/dispbbs.asp?BoardID=4&ID=2183&skin=0

本示例以后台自动交易的方式，展现了金字塔实现延迟信号确认的工作原理。

本代码可以实现3天现上穿5天线后，20秒等待信号确认后，再发开仓单。

请选择固定时间间隔模式运行后台自动交易，间隔时间设为1秒

本公式会在运行时产生很多临时数据，请用户再第二天交易前清空这些历史变量，否则会导致与第二天的临时变量冲突。方法 工具菜单－》数据－》全局变量，进去后，选择“清空”按钮

MA1:=MA(CLOSE,3);
MA2:=MA(CLOSE,5);

CROS:=CROSS(MA1,MA2);

CROS2:=CROSS(MA2,MA1);

BUY1:=FALSE;

IF ISLASTBAR THEN
BEGIN
 IF CROS THEN
 BEGIN
  //将当前信号周期置全局变量数据库
  //数据名字前加信号周期，标记周期位置
  CRTEMP:='TEMP1'&NUMTOSTR( BARPOS, 0);
  
  //读取原有变量的时间，判断是否到延时时间
  BUYTIME1:=EXTGBDATA(CRTEMP);
  BUYTIME2:=TIMETOT0(CURRENTTIME);
  DEBUGOUT('D1 %.0f',BUYTIME1);
  IF BUYTIME1 > 1 THEN //第一次信号的原数据库读取会得到0值
  BEGIN
   DEBUGOUT('D2 %.0f',BUYTIME2 - BUYTIME1);
   IF BUYTIME2 - BUYTIME1 > 20 THEN
   BEGIN
    //大于20秒的延迟，表示信号已经得到确认
    BUY1:=TRUE;
   END
  END
  ELSE
  BEGIN
   //第一次信号位置记录
   EXTGBDATASET(CRTEMP,TIMETOT0(CURRENTTIME));
  END
 END
 ELSE
 BEGIN
  //否则表示信号中间消失了
  CRTEMP:='TEMP1'&NUMTOSTR( BARPOS, 0);
  EXTGBDATASET(CRTEMP,0);
 END
END

TBUY(BUY1,1,MKT);
TSELL(CROS2,0,MKT);