您现在的位置：程序化交易>> 外汇现货>> MT5>> MT5公式>>正文内容

头寸大小计算器 (MT4 MT5指标)[MT5公式]

作者：MT4 MT5 来源：本站原创发布时间：2012年05月13日点击数：　【收藏到本网的会员中心】

这是为交易商提供的一个免费的在线工具— 头寸大小计算器。该指标适合MT4和MT5。

头寸大小计算器 (MetaTrader 指标) — 通过给定进场/止损水平、风险承受水平和当前市场数据，比如账户大小和货币，所交易货币对报价货币相对账户货币的价格，来计算头寸手数。计算结果将以文本标签的形式显示在主图表窗口。交易商可以调整众多参数，包括计算和显示。

输入参数：

EntryLevel (默认 = 0) — 计划开启头寸的价位。

StopLossLevel (默认 = 0) — 计划开启头寸的止损价位。

Risk (默认 = 1) — 账户余额/资产承受风险的百分比点数。

UseEquityInsteadOfBalance (默认 = false) — 如果选择true，计算时将以账户资金净值代理账户余额。

font_color (默认 = LightBlue/clrLightBlue) — 指标数据显示的字体颜色。

ps_font_color (默认 = Red/clrRed) — 头寸大小计算结果的字体颜色。

font_size (默认 = 12) — 显示文本的字体大小。

font_face (默认 = "Courier") — 指标的字体风格。

corner (默认 = 0/CORNER_LEFT_UPPER) — 指标文本的位置。在MT4上：0 — 代表左上角，1 —代表右上角，2 — 代表左下角，3 — 代表右下角。在MT5上，非常明显。

distance_x (默认 = 10) — 指标文本的位置到指标文本的水平距离。

distance_y (默认 = 130) — 指标文本的位置到指标文本的垂直距离。

entry_line_color (默认 = Blue/clrBlue) — 入场线的颜色。

stop_loss_line_color (默认 = Lime/clrLime) — 止损线的颜色。

很显然，该指标不是用来发出交易信号的。它的作用是帮助外汇交易商计算在他们允许的风险承受水平和给定头寸参数的条件下计算头寸的大小。

该指标需要将计划开启订单的价位和止损参数设置为非零的数值。这些值也必须为不同的数值。您可以将进场/止损线直接在图表上上下拖拽。头寸大小会随着每条线的每次移动而重新计算（仅适用于MT5）。

标签:MT4 MT5指标源码

MT4源码：


//+------------------------------------------------------------------+
//|                                       PositionSizeCalculator.mq4 |
//|                                  Copyright � 2012, Andriy Moraru |
//+------------------------------------------------------------------+
#property copyright "www.cxh99.com"
#property link      "http://www.cxh99.com"

/*
   Calculates position size based on account balance/equity,
   currency, currency pair, given entry level, stop-loss level
   and risk tolerance (set either in percentage points or in base currency).
*/

#property indicator_chart_window

extern double EntryLevel = 0;
extern double StopLossLevel = 0;
extern double Risk = 1; // Risk tolerance in percentage points
extern double MoneyRisk = 0; // Risk tolerance in base currency
extern bool UseMoneyInsteadOfPercentage = false;
extern bool UseEquityInsteadOfBalance = false;

extern color font_color = LightBlue;
extern color ps_font_color = Red;
extern int font_size = 12;
extern string font_face = "Courier";
extern int corner = 0; //0 - for top-left corner, 1 - top-right, 2 - bottom-left, 3 - bottom-right
extern int distance_x = 10;
extern int distance_y = 15;
extern color entry_line_color = Blue;
extern color stoploss_line_color = Lime;

string QuoteCurrency = "", ReferencePair = "";
double ReferencePrice = 0;
int ReferenceType = -1;
string ModeText, SizeText;
double Size, RiskMoney;
double PositionSize;
double StopLoss;
double UnitCost = 1;

void InitializeReferencePair()
{
   // Try Ask for AccountCurrency/QouteCurrency
   ReferencePair = AccountCurrency() + QuoteCurrency;
   ReferenceType = MODE_ASK;
   ReferencePrice = MarketInfo(ReferencePair, ReferenceType);
   // Try Bid for QuoteCurrency/AccountCurrency
   if (!ReferencePrice)
   {
      ReferencePair = QuoteCurrency + AccountCurrency();
      ReferenceType = MODE_BID;
      ReferencePrice = MarketInfo(ReferencePair, ReferenceType);
   }
   
   if (!ReferencePrice)
   {
      Alert("Failed to detect a proper currency pair for pip valuation.");
      Alert("Try adding all the available currency pairs to Market Watch.");
      ReferenceType = -1;
      return;
   }

   if (ReferenceType == MODE_BID) ModeText = "Bid";
   else if (ReferenceType == MODE_ASK) ModeText = "Ask";
   ObjectCreate("ReferencePair", OBJ_LABEL, 0, 0, 0);
   ObjectSet("ReferencePair", OBJPROP_CORNER, corner);
   ObjectSet("ReferencePair", OBJPROP_XDISTANCE, distance_x);
   ObjectSet("ReferencePair", OBJPROP_YDISTANCE, distance_y + 30);
   ObjectSetText("ReferencePair", ReferencePair + " " + ModeText + ":   " + DoubleToStr(ReferencePrice, Digits), font_size, font_face, font_color);
}

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
   if (EntryLevel - StopLossLevel == 0)
   {
      Alert("Entry and Stop-Loss levels should be different and non-zero.");
      return(-1);
   }

   // Determine the symbol quote currency
   if ((StringSubstr(Symbol(), 0, 1) == "#") || (StringFind(Symbol(), ".") != -1) || (StringFind(Symbol(), "_") != -1)) QuoteCurrency = "USD"; // CFD
   else if ((StringLen(Symbol()) != 6) && (StringSubstr(Symbol(), 0, 1) != "m") && (StringSubstr(Symbol(), 0, 1) != "x")) QuoteCurrency = "USD"; // Some commodity?
   else QuoteCurrency = StringSubstr(Symbol(), 3, 3); // Currency pair

   // Need to take into account the rate (Bid or Ask) of a reference currency pair
   // Can do it only if connected to account
   if ((AccountCurrency() != QuoteCurrency) && (AccountCurrency() != "")) InitializeReferencePair();
   
   ObjectCreate("Entry", OBJ_LABEL, 0, 0, 0);
   ObjectSet("Entry", OBJPROP_CORNER, corner);
   ObjectSet("Entry", OBJPROP_XDISTANCE, distance_x);
   ObjectSet("Entry", OBJPROP_YDISTANCE, distance_y);
   ObjectSetText("Entry", "Entry Lvl:    " + DoubleToStr(EntryLevel, Digits), font_size, font_face, font_color);

   ObjectCreate("EntryLine", OBJ_HLINE, 0, Time[0], EntryLevel);
   ObjectSet("EntryLine", OBJPROP_STYLE, STYLE_SOLID);
   ObjectSet("EntryLine", OBJPROP_COLOR, entry_line_color);
   ObjectSet("EntryLine", OBJPROP_WIDTH, 1);

   ObjectCreate("StopLoss", OBJ_LABEL, 0, 0, 0);
   ObjectSet("StopLoss", OBJPROP_CORNER, corner);
   ObjectSet("StopLoss", OBJPROP_XDISTANCE, distance_x);
   ObjectSet("StopLoss", OBJPROP_YDISTANCE, distance_y + 15);
   ObjectSetText("StopLoss", "Stop-Loss:    " + DoubleToStr(StopLossLevel, Digits), font_size, font_face, font_color);
   
   ObjectCreate("StopLossLine", OBJ_HLINE, 0, Time[0], StopLossLevel);
   ObjectSet("StopLossLine", OBJPROP_STYLE, STYLE_SOLID);
   ObjectSet("StopLossLine", OBJPROP_COLOR, stoploss_line_color);
   ObjectSet("StopLossLine", OBJPROP_WIDTH, 1);

   StopLoss = MathAbs(EntryLevel - StopLossLevel);
   
   if (!UseMoneyInsteadOfPercentage)
   {
      ObjectCreate("Risk", OBJ_LABEL, 0, 0, 0);
      ObjectSet("Risk", OBJPROP_CORNER, corner);
      ObjectSet("Risk", OBJPROP_XDISTANCE, distance_x);
      ObjectSet("Risk", OBJPROP_YDISTANCE, distance_y + 45);
      ObjectSetText("Risk", "Risk:         " + DoubleToStr(Risk, 2) + "%", font_size, font_face, font_color);
   }
   
   if (UseEquityInsteadOfBalance)
   {
      SizeText = "Equity";
      Size = AccountEquity();
   }
   else
   {
      SizeText = "Balance";
      Size = AccountBalance();
   }
   ObjectCreate("AccountSize", OBJ_LABEL, 0, 0, 0);
   ObjectSet("AccountSize", OBJPROP_CORNER, corner);
   ObjectSet("AccountSize", OBJPROP_XDISTANCE, distance_x);
   ObjectSet("AccountSize", OBJPROP_YDISTANCE, distance_y + 60);
   ObjectSetText("AccountSize", "Acc. " + SizeText + ": " + DoubleToStr(Size, 2), font_size, font_face, font_color);
   
   if (!UseMoneyInsteadOfPercentage) RiskMoney = Size * Risk / 100;
   else RiskMoney = MoneyRisk;
   ObjectCreate("RiskMoney", OBJ_LABEL, 0, 0, 0);
   ObjectSet("RiskMoney", OBJPROP_CORNER, corner);
   ObjectSet("RiskMoney", OBJPROP_XDISTANCE, distance_x);
   ObjectSet("RiskMoney", OBJPROP_YDISTANCE, distance_y + 75);
   ObjectSetText("RiskMoney", "Risk, money:  " + DoubleToStr(RiskMoney, 2), font_size, font_face, font_color);
   
   
   if (ReferenceType == MODE_ASK)
   {
      RefreshRates();
      ReferencePrice = MarketInfo(ReferencePair, ReferenceType);
      UnitCost = 1 / ReferencePrice;
   }
	else if (ReferenceType == MODE_BID)
	{
      RefreshRates();
      ReferencePrice = MarketInfo(ReferencePair, ReferenceType);
      UnitCost = ReferencePrice;
   }

   ObjectCreate("PositionSize", OBJ_LABEL, 0, 0, 0);
   ObjectSet("PositionSize", OBJPROP_CORNER, corner);
   ObjectSet("PositionSize", OBJPROP_XDISTANCE, distance_x);
   ObjectSet("PositionSize", OBJPROP_YDISTANCE, distance_y + 90);

   if ((ReferenceType != -1) && (AccountCurrency() != QuoteCurrency)) return(0);

   PositionSize = (RiskMoney / StopLoss) / 100000 / UnitCost;
   ObjectSetText("PositionSize", "Pos. Size:    " + DoubleToStr(PositionSize, 2), font_size + 1, font_face, ps_font_color);

   return(0);
}

//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
{
   ObjectDelete("Entry");
   ObjectDelete("EntryLine");
   ObjectDelete("StopLoss");
   ObjectDelete("StopLossLine");
   if (!UseMoneyInsteadOfPercentage) ObjectDelete("Risk"); // Otherwise wasn't created.
   ObjectDelete("ReferencePair");
   ObjectDelete("AccountSize");
   ObjectDelete("RiskMoney");
   ObjectDelete("PositionSize");
   return(0);
}

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{
   if (EntryLevel - StopLossLevel == 0) return(0);
   
   // Need to initialize reference pair because we couldn't do it in init() as the there was no connection to account
   if ((AccountCurrency() != QuoteCurrency) && (ReferencePair == ""))
   {
      if (AccountCurrency() == "") return(0);
      InitializeReferencePair();
   }
   
   double tEntryLevel = ObjectGet("EntryLine", OBJPROP_PRICE1);
   double tStopLossLevel = ObjectGet("StopLossLine", OBJPROP_PRICE1);
   ObjectSetText("Entry", "Entry Lvl:    " + DoubleToStr(tEntryLevel, Digits), font_size, font_face, font_color);
   ObjectSetText("StopLoss", "Stop-Loss:    " + DoubleToStr(tStopLossLevel, Digits), font_size, font_face, font_color);

   StopLoss = MathAbs(tEntryLevel - tStopLossLevel);

   if (UseEquityInsteadOfBalance) Size = AccountEquity();
   else Size = AccountBalance();
   ObjectSetText("AccountSize", "Acc. " + SizeText + ": " + DoubleToStr(Size, 2), font_size, font_face, font_color);

   if (!UseMoneyInsteadOfPercentage) RiskMoney = Size * Risk / 100;
   else RiskMoney = MoneyRisk;
   ObjectSetText("RiskMoney", "Risk, money:  " + DoubleToStr(RiskMoney, 2), font_size, font_face, font_color);

   if (ReferenceType != -1)
   {
      ReferencePrice = MarketInfo(ReferencePair, ReferenceType);
      ObjectSetText("ReferencePair", ReferencePair + " " + ModeText + ":   " + DoubleToStr(ReferencePrice, Digits), font_size, font_face, font_color);
   
      if (ReferenceType == MODE_ASK) UnitCost = 1 / ReferencePrice;
	   else if (ReferenceType == MODE_BID) UnitCost = ReferencePrice;
   }

   PositionSize = (RiskMoney / StopLoss) / 100000 / UnitCost;
   
   ObjectSetText("PositionSize", "Pos. Size:    " + DoubleToStr(PositionSize, 2), font_size + 1, font_face, ps_font_color);
   
   return(0);
}
//+------------------------------------------------------------------+

MT5源码：

//+------------------------------------------------------------------+
//|                                       PositionSizeCalculator.mq5 |
//|                                  Copyright � 2012, Andriy Moraru |
//+------------------------------------------------------------------+
#property copyright "www.cxh99.com"
#property link      "http://www.cxh99.com"
#property version   "1.1"

#property description "Calculates position size based on account balance/equity,"
#property description "currency, currency pair, given entry level, stop-loss level"
#property description "and risk tolerance (set either in percentage points or in base currency)."
#property description " "
#property description "2012-05-10, ver. 1.1 - added support for setting risk in money."

#property indicator_chart_window

input double EntryLevel = 0;
input double StopLossLevel = 0;
input double Risk = 1; // Risk tolerance in percentage points
input double MoneyRisk = 0; // Risk tolerance in base currency
input bool UseMoneyInsteadOfPercentage = false;
input bool UseEquityInsteadOfBalance = false;

input color font_color = clrLightBlue;
input color ps_font_color = clrRed;
input int font_size = 12;
input string font_face = "Courier";
input ENUM_BASE_CORNER corner = CORNER_LEFT_UPPER;
input int distance_x = 10;
input int distance_y = 15;
input color entry_line_color = clrBlue;
input color stoploss_line_color = clrLime;

string QuoteCurrency = "", ReferencePair = "";
double ReferencePrice = 0;
ENUM_SYMBOL_INFO_DOUBLE ReferenceType = -1;
string ModeText, SizeText;
double Size, RiskMoney;
double PositionSize;
double StopLoss;
double UnitCost = 1;

void InitializeReferencePair()
{
   // Try Ask for AccountCurrency/QouteCurrency
   ReferencePair = AccountInfoString(ACCOUNT_CURRENCY) + QuoteCurrency;
   ReferenceType = SYMBOL_ASK;
   ReferencePrice = SymbolInfoDouble(ReferencePair, ReferenceType);
   // Try Bid for QuoteCurrency/AccountCurrency
   if (!ReferencePrice)
   {
      ReferencePair = QuoteCurrency + AccountInfoString(ACCOUNT_CURRENCY);
      ReferenceType = SYMBOL_BID;
      ReferencePrice = SymbolInfoDouble(ReferencePair, ReferenceType);
   }
   
   if (!ReferencePrice)
   {
      Alert("Failed to detect a proper currency pair for pip valuation.");
      Alert("Try adding all the available currency pairs to Market Watch.");
      ReferenceType = -1;
      return;
   }

   if (ReferenceType == SYMBOL_BID) ModeText = "Bid";
   else if (ReferenceType == SYMBOL_ASK) ModeText = "Ask";
   ObjectCreate(0, "ReferencePair", OBJ_LABEL, 0, 0, 0);
   ObjectSetInteger(0, "ReferencePair", OBJPROP_CORNER, corner);
   ObjectSetInteger(0, "ReferencePair", OBJPROP_XDISTANCE, distance_x);
   ObjectSetInteger(0, "ReferencePair", OBJPROP_YDISTANCE, distance_y + 30);
   ObjectSetString(0, "ReferencePair", OBJPROP_TEXT, ReferencePair + " " + ModeText + ":   " + DoubleToString(ReferencePrice, _Digits));
   ObjectSetInteger(0, "ReferencePair", OBJPROP_FONTSIZE, font_size);
   ObjectSetString(0, "ReferencePair", OBJPROP_FONT, font_face);
   ObjectSetInteger(0, "ReferencePair", OBJPROP_COLOR, font_color);
}

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
void OnInit()
{
   if (EntryLevel - StopLossLevel == 0)
   {
      Alert("Entry and Stop-Loss levels should be different and non-zero.");
      return;
   }

   // Determine the symbol quote currency
   if ((StringSubstr(Symbol(), 0, 1) == "#") || (StringFind(Symbol(), ".") != -1) || (StringFind(Symbol(), "_") != -1)) QuoteCurrency = "USD"; // CFD
   else if ((StringLen(Symbol()) != 6) && (StringSubstr(Symbol(), 0, 1) != "m") && (StringSubstr(Symbol(), 0, 1) != "x")) QuoteCurrency = "USD"; // Some commodity?
   else QuoteCurrency = StringSubstr(Symbol(), 3, 3); // Currency pair

   // Need to take into account the rate (Bid or Ask) of a reference currency pair
   // Can do it only if connected to account
   if ((AccountInfoString(ACCOUNT_CURRENCY) != QuoteCurrency) && (AccountInfoString(ACCOUNT_CURRENCY) != "")) InitializeReferencePair();
   
   ObjectCreate(0, "Entry", OBJ_LABEL, 0, 0, 0);
   ObjectSetInteger(0, "Entry", OBJPROP_CORNER, corner);
   ObjectSetInteger(0, "Entry", OBJPROP_XDISTANCE, distance_x);
   ObjectSetInteger(0, "Entry", OBJPROP_YDISTANCE, distance_y);
   ObjectSetString(0, "Entry", OBJPROP_TEXT, "Entry Lvl:    " + DoubleToString(EntryLevel, _Digits));
   ObjectSetInteger(0, "Entry", OBJPROP_FONTSIZE, font_size);
   ObjectSetString(0, "Entry", OBJPROP_FONT, font_face);
   ObjectSetInteger(0, "Entry", OBJPROP_COLOR, font_color);

   
   ObjectCreate(0, "EntryLine", OBJ_HLINE, 0, TimeCurrent(), EntryLevel);
   ObjectSetInteger(0, "EntryLine", OBJPROP_STYLE, STYLE_SOLID);
   ObjectSetInteger(0, "EntryLine", OBJPROP_COLOR, entry_line_color);
   ObjectSetInteger(0, "EntryLine", OBJPROP_WIDTH, 1);
   ObjectSetInteger(0, "EntryLine", OBJPROP_SELECTABLE, true);

   ObjectCreate(0, "StopLoss", OBJ_LABEL, 0, 0, 0);
   ObjectSetInteger(0, "StopLoss", OBJPROP_CORNER, corner);
   ObjectSetInteger(0, "StopLoss", OBJPROP_XDISTANCE, distance_x);
   ObjectSetInteger(0, "StopLoss", OBJPROP_YDISTANCE, distance_y + 15);
   ObjectSetString(0, "StopLoss", OBJPROP_TEXT, "Stop-Loss:    " + DoubleToString(StopLossLevel, _Digits));
   ObjectSetInteger(0, "StopLoss", OBJPROP_FONTSIZE, font_size);
   ObjectSetString(0, "StopLoss", OBJPROP_FONT, font_face);
   ObjectSetInteger(0, "StopLoss", OBJPROP_COLOR, font_color);

   ObjectCreate(0, "StopLossLine", OBJ_HLINE, 0, TimeCurrent(), StopLossLevel);
   ObjectSetInteger(0, "StopLossLine", OBJPROP_STYLE, STYLE_SOLID);
   ObjectSetInteger(0, "StopLossLine", OBJPROP_COLOR, stoploss_line_color);
   ObjectSetInteger(0, "StopLossLine", OBJPROP_WIDTH, 1);
   ObjectSetInteger(0, "StopLossLine", OBJPROP_SELECTABLE, true);

   StopLoss = MathAbs(EntryLevel - StopLossLevel);
   
   if (!UseMoneyInsteadOfPercentage)
   {
      ObjectCreate(0, "Risk", OBJ_LABEL, 0, 0, 0);
      ObjectSetInteger(0, "Risk", OBJPROP_CORNER, corner);
      ObjectSetInteger(0, "Risk", OBJPROP_XDISTANCE, distance_x);
      ObjectSetInteger(0, "Risk", OBJPROP_YDISTANCE, distance_y + 45);
      ObjectSetString(0, "Risk", OBJPROP_TEXT, "Risk:         " + DoubleToString(Risk, 2) + "%");
      ObjectSetInteger(0, "Risk", OBJPROP_FONTSIZE, font_size);
      ObjectSetString(0, "Risk", OBJPROP_FONT, font_face);
      ObjectSetInteger(0, "Risk", OBJPROP_COLOR, font_color);
   }
   
   if (UseEquityInsteadOfBalance)
   {
      SizeText = "Equity";
      Size = AccountInfoDouble(ACCOUNT_EQUITY);
   }
   else
   {
      SizeText = "Balance";
      Size = AccountInfoDouble(ACCOUNT_BALANCE);
   }
   ObjectCreate(0, "AccountSize", OBJ_LABEL, 0, 0, 0);
   ObjectSetInteger(0, "AccountSize", OBJPROP_CORNER, corner);
   ObjectSetInteger(0, "AccountSize", OBJPROP_XDISTANCE, distance_x);
   ObjectSetInteger(0, "AccountSize", OBJPROP_YDISTANCE, distance_y + 60);
   ObjectSetString(0, "AccountSize", OBJPROP_TEXT, "Acc. " + SizeText + ": " + DoubleToString(Size, 2));
   ObjectSetInteger(0, "AccountSize", OBJPROP_FONTSIZE, font_size);
   ObjectSetString(0, "AccountSize", OBJPROP_FONT, font_face);
   ObjectSetInteger(0, "AccountSize", OBJPROP_COLOR, font_color);
   
   if (!UseMoneyInsteadOfPercentage) RiskMoney = Size * Risk / 100;
   else RiskMoney = MoneyRisk;
   ObjectCreate(0, "RiskMoney", OBJ_LABEL, 0, 0, 0);
   ObjectSetInteger(0, "RiskMoney", OBJPROP_CORNER, corner);
   ObjectSetInteger(0, "RiskMoney", OBJPROP_XDISTANCE, distance_x);
   ObjectSetInteger(0, "RiskMoney", OBJPROP_YDISTANCE, distance_y + 75);
   ObjectSetString(0, "RiskMoney", OBJPROP_TEXT, "Risk, money:  " + DoubleToString(RiskMoney, 2));
   ObjectSetInteger(0, "RiskMoney", OBJPROP_FONTSIZE, font_size);
   ObjectSetString(0, "RiskMoney", OBJPROP_FONT, font_face);
   ObjectSetInteger(0, "RiskMoney", OBJPROP_COLOR, font_color);
   
   
   if (ReferenceType == SYMBOL_ASK)
   {
      ReferencePrice = SymbolInfoDouble(ReferencePair, ReferenceType);
      UnitCost = 1 / ReferencePrice;
   }
	else if (ReferenceType == SYMBOL_BID)
	{
      ReferencePrice = SymbolInfoDouble(ReferencePair, ReferenceType);
      UnitCost = ReferencePrice;
   }

   ObjectCreate(0, "PositionSize", OBJ_LABEL, 0, 0, 0);
   ObjectSetInteger(0, "PositionSize", OBJPROP_CORNER, corner);
   ObjectSetInteger(0, "PositionSize", OBJPROP_XDISTANCE, distance_x);
   ObjectSetInteger(0, "PositionSize", OBJPROP_YDISTANCE, distance_y + 90);
   ObjectSetInteger(0, "PositionSize", OBJPROP_FONTSIZE, font_size + 1);
   ObjectSetString(0, "PositionSize", OBJPROP_FONT, font_face);
   ObjectSetInteger(0, "PositionSize", OBJPROP_COLOR, ps_font_color);

   if ((ReferenceType != -1) && (AccountInfoString(ACCOUNT_CURRENCY) != QuoteCurrency)) return;

   PositionSize = (RiskMoney / StopLoss) / 100000 / UnitCost;
   ObjectSetString(0, "PositionSize", OBJPROP_TEXT, "Pos. Size:    " + DoubleToString(PositionSize, 2));
}

//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
   ObjectDelete(0, "Entry");
   ObjectDelete(0, "EntryLine");
   ObjectDelete(0, "StopLoss");
   ObjectDelete(0, "StopLossLine");
   if (!UseMoneyInsteadOfPercentage) ObjectDelete(0, "Risk"); // Otherwise wasn't created.
   ObjectDelete(0, "ReferencePair");
   ObjectDelete(0, "AccountSize");
   ObjectDelete(0, "RiskMoney");
   ObjectDelete(0, "PositionSize");
}

//+------------------------------------------------------------------+
//| Main recalculation function used on every tick and on entry/SL   |
//| line drag                                                        |
//+------------------------------------------------------------------+
void RecalculatePositionSize()
{
   if (EntryLevel - StopLossLevel == 0) return;
   
   // Need to initialize reference pair because we couldn't do it in init() as the there was no connection to account
   if ((AccountInfoString(ACCOUNT_CURRENCY) != QuoteCurrency) && (ReferencePair == ""))
   {
      if (AccountInfoString(ACCOUNT_CURRENCY) == "") return;
      InitializeReferencePair();
   }
   
   double tEntryLevel = ObjectGetDouble(0, "EntryLine", OBJPROP_PRICE);
   double tStopLossLevel = ObjectGetDouble(0, "StopLossLine", OBJPROP_PRICE);
   ObjectSetString(0, "Entry", OBJPROP_TEXT, "Entry Lvl:    " + DoubleToString(tEntryLevel, _Digits));
   ObjectSetString(0, "StopLoss", OBJPROP_TEXT, "Stop-Loss:    " + DoubleToString(tStopLossLevel, _Digits));

   StopLoss = MathAbs(tEntryLevel - tStopLossLevel);

   if (UseEquityInsteadOfBalance) Size = AccountInfoDouble(ACCOUNT_EQUITY);
   else Size = AccountInfoDouble(ACCOUNT_BALANCE);
   ObjectSetString(0, "AccountSize", OBJPROP_TEXT, "Acc. " + SizeText + ": " + DoubleToString(Size, 2));

   if (!UseMoneyInsteadOfPercentage) RiskMoney = Size * Risk / 100;
   else RiskMoney = MoneyRisk;
   ObjectSetString(0, "RiskMoney", OBJPROP_TEXT, "Risk, money:  " + DoubleToString(RiskMoney, 2));

   if (ReferenceType != -1)
   {
      ReferencePrice = SymbolInfoDouble(ReferencePair, ReferenceType);
      ObjectSetString(0, "ReferencePair", OBJPROP_TEXT, ReferencePair + " " + ModeText + ":   " + DoubleToString(ReferencePrice, _Digits));
   
      if (ReferenceType == SYMBOL_ASK) UnitCost = 1 / ReferencePrice;
	   else if (ReferenceType == SYMBOL_BID) UnitCost = ReferencePrice;
   }

   PositionSize = (RiskMoney / StopLoss) / 100000 / UnitCost;
   
   ObjectSetString(0, "PositionSize", OBJPROP_TEXT, "Pos. Size:    " + DoubleToString(PositionSize, 2));
}

//+------------------------------------------------------------------+
//| Object dragging handler                                          |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,         // Event ID
                  const long& lparam,   // Parameter of type long event
                  const double& dparam, // Parameter of type double event
                  const string& sparam  // Parameter of type string events
)
{
   if (id != CHARTEVENT_OBJECT_DRAG) return;
   if ((sparam != "EntryLine") && (sparam != "StopLossLine")) return;
   RecalculatePositionSize();
}

int OnCalculate(const int rates_total,      // size of the price[] array
                 const int prev_calculated,  // bars handled on a previous call
                 const int begin,            // where the significant data start from
                 const double& price[]       // array to calculate
)
{
   RecalculatePositionSize();
   return(rates_total);
}
//+------------------------------------------------------------------+

【字体：小大】【打印文章】【查看评论】

上一篇：Price Alert (价格预警指标MT4 MT5指标)
下一篇：没有了！

没有相关内容

头寸大小计算器 (MT4 MT5指标)[MT5公式]

输入参数：

相关文章

栏目导航

本月热门排行

会员登录/注册