您现在的位置：程序化交易>> 期货公式>> 交易开拓者(TB)>> 开拓者知识>>正文内容

跨周期数据转换函数以及跨周期技术指标调用的实现 - TradeBlazer公式　[开拓者 TB]

作者：开拓者 TB 来源：cxh99.com 发布时间：2013年02月24日 点击数： 　【收藏到本网的会员中心】
  • 咨询内容： 本帖最后由 追涨杀跌 于 2011-12-26 14:17 编辑

    TB的跨周期调用，以前已经有一些解决方案。但总体来说，使用还不够方便。以前的帖子中Nopain曾提出过一个算法，非常精巧。最近在这个算法的基础上， 把整个实现方法完善了一下。下面把总体思路和函数代码贴出来，请大家试用，也欢迎大家提出修改意见。

    总体思路：
    1、小周期调用大周期的数据；
    2、具体方法是新编一个函数，用来根据小周期下的数据推算出大周期的BAR数据，为了省事，计算时，会将大周期下的开高低收以及成交量和持仓量等数据都算出来，然后将这些数据通过引用参数返回。当然有的朋友可能只需要一个收盘价就可以了，那样的话，可以自行修改这个函数，把多余的数据去掉；
    3、返回的大周期数据将以序列变量的形式保留在对应的小周期K线上，以便以后调用；
    4、另外为了便于大周期的数据计算出来后的回溯使用，函数会将小周期下当前BAR到大周期下的前一个BAR的最后一个小周期BAR需要回溯的BAR数目，作为函数的结果返回。这句话，不容易描述清楚，估计大家听起来也费力，但没关系，后面用例子来解释，知道这回事就行了。
    5、另外还增加了一个返回值（也是通过引用参数返回），表示的是当前小周期K线对应的大周期K线在整个大周期中的索引值。举例来说，5分钟图，样本数300，那转换成30分钟周期图，总共应该是50根K线，那最新一根5分钟图对应的30分钟K线在整个30分钟图中的索引值就应该是49（类似CurrentBar 0-49）；

    好，其他先不废话，把代码贴出来，再举几个例子。

    新建用户函数MtBar, 返回值为数值类型，代码如下：
    1. Params
    2.         Numeric TimeFrame(1440);   
    3.         // 目标时间周期：月线=40320，周线=10080，日线=1440，4小时线=240
    4.         // 其他1小时内的周期等于相应的分钟数，如：1小时=60， 30分钟=30。。。
    5.         // 支持不规则分钟数，如3分钟，8分钟，之类都行
    6.         
    7.         Numeric BarsBack(1);
    8.         // 目标时间周期BAR偏移：
    9.         // 1--表示将目标时间周期下的前1根K线数据作为与当前Bar对应的目标时间周期下的K线数据
    10.         // 0--表示将目标时间周期下的截止到目前为止的数据转换为与当前BAR对应的目标时间周期下K线数据
    11.         
    12.         NumericRef oCurBar;                 // 目标时间周期下的Bar索引
    13.         NumericRef oOPenHT;         // 目标时间周期下的开盘价
    14.         NumericRef oHighHT;         // 目标时间周期下的最高价
    15.         NumericRef oLowHT;          // 目标时间周期下的最低价
    16.         NumericRef oCloseHT;        // 目标时间周期下的收盘价
    17.         NumericRef oVolHT;          // 目标时间周期下的成交量
    18.         NumericRef oOpenIntHT;      // 目标时间周期下的持仓量

    20. Vars
    21.         NumericSeries barCnt;
    22.         NumericSeries CurBar;
    23.         NumericSeries barCntSum;
    24.         NumericSeries OpenHT;
    25.         NumericSeries HighHT;
    26.         NumericSeries LowHT;
    27.         NumericSeries CloseHT;
    28.         NumericSeries VolHT;
    29.         NumericSeries OpenIntHT;
    30.         Numeric CurTime;
    31.         Numeric PreTime;
    32.         bool condition(false);
    33.         Numeric i;
    34. Begin
    35.         If (TimeFrame == 40320)                 // 月线
    36.         {
    37.                 CurTime = Month;
    38.                 PreTime = Month[1];
    39.         }
    40.         Else If (TimeFrame == 10080)                        // 周线
    41.         {
    42.                 CurTime = IntPart(DateDiff(19700105,Date)/7);
    43.                 PreTime = IntPart(DateDiff(19700105,Date[1])/7);
    44.         }
    45.         Else                                                                        // 其他时间周期
    46.         {
    47.                 CurTime = IntPart((DateDiff(19700105,date)*1440 + Hour*60 + Minute)/TimeFrame);
    48.                 PreTime = IntPart((DateDiff(19700105,date[1])*1440 + Hour[1]*60 + Minute[1])/TimeFrame);
    49.         }
    50.         condition = CurTime != PreTime;

    52.         If (CurrentBar==0)                // 如果是第一根Bar, CurBar=0
    53.         {
    54.                 barCnt = 0;
    55.                 CurBar = 0;
    56.                 OpenHT = Open;
    57.                 HighHT = High;
    58.                 LowHT = Low;
    59.                 CloseHT = Close;
    60.                 VolHT = Vol;
    61.                 OpenIntHT = OpenInt;
    62.         }
    63.         Else
    64.         {
    65.                 If(Condition)               
    66.                 // 如果在目标周期下，属于另一根K线，则CurBar加1
    67.                 {
    68.                         barCnt = 1;
    69.                         CurBar = CurBar[1] + 1;
    70.                         OpenHT = Open;
    71.                         HighHT = High;
    72.                         LowHT = Low;
    73.                         VolHT = Vol;
    74.                 }Else
    75.                 // 如果在目标周期下，属于同一根K线，则CurBar不变，但最高价和最低价要记录价格的变化，成交量要累加
    76.                 {
    77.                         barCnt = barCnt[1] + 1;
    78.                         CurBar = CurBar[1];
    79.                         OpenHT = OpenHT[1];
    80.                         HighHT = Max(HighHT[1],High);
    81.                         LowHT = Min(LowHT[1],Low);
    82.                         VolHT = VolHT[1] + Vol;
    83.                 }
    84.                 // 收盘价和持仓量总是取最新值
    85.                 CloseHT = Close;
    86.                 OpenIntHT = OpenInt;
    87.         }
    88.         
    89.         // 上面的程序，在每根小周期的K线上，记录了它所属的大时间周期下的开高低收等值的变化。
    90.         // 接下来，要把在大的时间周期级别上，属于同一根K线的开高低收这些数据，记录在这一组小周期K线的最后一根上。
    91.         barCntSum = barCnt ;
    92.         If(BarsBack == 0)
    93.         // 如果Bar偏移参数为0，则取每根小周期K线上保留的大时间周期截止到这根小周期K线为止的BAR数据
    94.         {
    95.                 barCntSum = 0 ;
    96.         }Else If(BarsBack == 1)
    97.         // 如果Bar偏移参数为1，则取大时间周期的上一根K线的BAr数据
    98.         {
    99.                 barCntSum = barCnt ;
    100.         }Else
    101.         // 如果BAR偏移参数为其他，则取大时间周期的指定偏移后的那根K线的BAR数据
    102.         {
    103.                 For i = 2 To BarsBack
    104.                 {
    105.                         barCntSum = barCntSum + barCnt[barCntSum];
    106.                 }
    107.         }

    109.         // 最后将相应的K线数据作为引用参数返回
    110.         oCurBar = CurBar;
    111.         oOpenHT = OpenHT[barCntSum];
    112.         oHighHT = HighHT[barCntSum];
    113.         oLowHT = LowHT[barCntSum];
    114.         oCloseHT = CloseHT[barCntSum];
    115.         oVolHT = VolHT[barCntSum];
    116.         oOpenIntHT = OpenIntHT[barCntSum];
    117.         Return barCnt;
    118. End

     

  • TB技术人员： 忘了说一句，以上代码是在TB V4中编写与调试的。

    接下来，我们来实现跨周期的求和函数MtSummation，上面的函数中特地返回了一个值oCurBar，就是我上面提到的大周期下的BAR索引值，就是想为实现MtSummationFC留下的伏笔，等以后有时间再解决。现在先还是用最笨的循环累加的算法。
    1. Params
    2.         NumericSeries Price(1);
    3.         NumericSeries BarCnt(0);
    4.         Numeric Length(10);
    5. Vars
    6.         NumericSeries SumValue(0);
    7.         Numeric i;
    8.         Numeric j(0);
    9. Begin
    10.         SumValue = 0;
    11.         For i = 1 to Length
    12.         {
    13.                 If (Price[j] <> InvalidNumeric)
    14.                 {
    15.                         SumValue = SumValue + Price[j];
    16.                         j = j + BarCnt[j];
    17.                 }
    18.                 else Break;
    19.         }
    20.         Return SumValue;
    21. End
    复制代码

     

  • TB客服： 接下来，就可以实现计算跨周期简单移动平均的函数MtMa。
    1. Params
    2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
    3.         Numeric BarsBack(1);                // 目标时间周期BAR偏移参数，说明见MtBar函数
    4.         Numeric Length(10);                        // 均线周期
    5.         NumericRef oMA;             // 以目标时间周期下的K线数据计算出的移动平均线
    6. Vars
    7.         NumericSeries mtBarCnt;
    8.         NumericSeries mtClose;
    9.         Numeric refCurBar;
    10.         Numeric refOpen;
    11.         Numeric refHigh;
    12.         Numeric refLow;
    13.         Numeric refClose;
    14.         Numeric refVol;
    15.         Numeric refOpenInt;
    16.        
    17.         Numeric SumValue(0);
    18.         Numeric i;
    19.         Numeric j(0);
    20. Begin
    21.         mtBarCnt = MtBar(TimeFrame,BarsBack,refCurBar,refOpen,refHigh,refLow,refClose,refVol,refOpenInt);
    22.         mtClose = refClose;

    24.         SumValue = MtSummation(mtClose,mtBarCnt,Length);
    25.         oMA = SumValue/Length;
    26.         Return mtBarCnt;
    27. End
    复制代码

     

  • 网友回复： 现在可以举个例子来说明，怎么用上面的几个函数来做交易策略了。假如我们的策略如下：
    1、我们以日线的均线交叉来判断大趋势，然后在5分钟图上来做交易；
    2、日线的短期均线上穿长期均线，则只做多，不做空；反之只做空，不做多；
    3、确定了大趋势后，我们再根据5分钟图来判断小趋势，以决定进场时机。我们仍然用均线来判断，在多头大趋势下，如果5分钟的短期均线上穿长期均线，则进场做多，反穿出场，但不反手做空；在空头大趋势下，类似；
    我们在5分钟图上调用刚才的函数的来实现。新建公式应用TestMtMa，代码如下：
    1. Params
    2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
    3.         Numeric BarsBack(1);                // 目标时间周期BAR偏移参数，说明见MtBar函数

    5.         Numeric Length1(10);                // 大周期的短期均线周期               
    6.         Numeric Length2(20);                // 大周期的长期均线周期
    7.         Numeric Length3(10);                // 小周期的短期均线周期
    8.         Numeric Length4(20);                // 小周期的长期均线周期
    9.         Numeric Lots(1);
    10. Vars
    11.         NumericSeries MA1;
    12.         NumericSeries MA2;
    13.         Numeric oMA1;
    14.         Numeric oMA2;

    16.         NumericSeries MA3;
    17.         NumericSeries MA4;
    18. Begin
    19.         MtMa(TimeFrame,BarsBack,Length1,oMA1);
    20.         MA1 = oMA1;
    21.         PlotNumeric("MA1",MA1);
    22.         MtMa(TimeFrame,BarsBack,Length2,oMA2);
    23.         MA2 = oMA2;
    24.         PlotNumeric("MA2",MA2);
    25.         MA3 = AverageFC(Close,Length3);
    26.         MA4 = AverageFC(Close,Length4);
    27.         PlotNumeric("MA3",MA3);
    28.         PlotNumeric("MA4",MA4);
    29.        
    30.        
    31.         If (MA1>MA2)                // 大周期均线金叉，多头趋势
    32.         {
    33.                 if (MarketPosition!=1 and MA3[1]>MA4[1])
    34.                 {
    35.                         Buy(Lots,Open);
    36.                 }
    37.                 if (MarketPosition==1 and MA3[1]<MA4[1])
    38.                 {
    39.                         Sell(Lots,Open);
    40.                 }
    41.         }
    42.         If (MA1<MA2)                // 大周期均线死叉，空头趋势
    43.         {
    44.                 if (MarketPosition!=-1 and MA3[1]<MA4[1])
    45.                 {
    46.                         SellShort(Lots,Open);
    47.                 }
    48.                 if (MarketPosition==-1 and MA3[1]>MA4[1])
    49.                 {
    50.                         BuyToCover(Lots,Open);
    51.                 }
    52.         }
    53. End
    复制代码

     

  • 网友回复： 如果上面的策略，我们不想用日线均线来判断大趋势，而改用小时线来判断，则只要将参数TimeFrame改为60, 就可以了。

 

有思路，想编写各种指标公式，程序化交易模型，选股公式，预警公式的朋友

可联系技术人员 QQ: 262069696  点击在线交流进行 有偿 编写！（不贵！点击查看价格！）


【字体：小 大】【打印文章】【查看评论】

相关文章

    没有相关内容

栏目导航

 本月热门排行

 用户常看内容